• šiek tiek kitokie įėjimo ir išėjimo laikotarpiai
• trendo filtras
• pelno fiksavimas, jei iki planuojamo išėjimo kaina patiria ekstremalius svyravimus
• įėjimo filtras esant žemam volatilumui
• įėjimo filtras esant ekstremaliai aukštam volatilumui
• atsisakymas įeiti tam tikrą savaitės dieną

// PJK: modifikuotas 3 dienų sandoris
// © P. J. Kaufman, 2018, 2020, 2023–2024. Visos teisės saugomos.
// ATRprofitfactor — naudoti ATR periodą pelno tikslui apskaičiuoti
// Dayofweek: 1 = sekmadienis
inputs: longentry(3), longexit(2), shortentry(4), shortexit(2),
trendper(0), profperiod(5), longproffactor(0), shortproffactor(0), longonly(true), dontusedayofweek(0),
usestocks(false), maxvol(0), minvol(0), volperiod(20);
vars: currentdir(0), upcount(0), downcount(0), prevupcount(0),
prevdowncount(0), trend(0), size(1), prevdir(0), positionATR(0), stockinvestment(10000), volOK(false), futuresinvestment(25000), basisperiod(20), DOW(0), avol(0), ATR(0), volratio(0), ATRprofit(0), raw(0);
if trendper > 0 then begin
if high > highest(high[1],trendper) then trend = 1 else if low < lowest(low[1],trendper) then trend = -1;
end;
DOW = dayofweek(date);
// ATR pagrįstas volatilumas
if volperiod <> 0 then begin
ATR = avgtruerange(volperiod);
if ATR[1] <> 0 then volratio = truerange/ATR[1];
end;
// pozicijos dydis
if usestocks then begin
size = stockinvestment/close[1];
end
else begin
positionATR = avgtruerange(basisperiod);
if positionATR <> 0 then
size = futuresinvestment/ (positionATR*bigpointvalue);
end;
// ATR pagrįstas pelno tikslas
if profperiod <> 0 then ATRprofit = avgtruerange(profperiod);
// serijos ilgio ir jos krypties skaičiavimas
prevupcount = upcount; prevdowncount = downcount;
prevdir = currentdir;
if close > close[1] then begin
if close[1] > close[2] then
upcount = upcount + 1 else begin
currentdir = 1;
upcount = 1;
downcount = 0;
end;
end
else if close < close[1] then begin
if close[1] < close[2] then
downcount = downcount + 1
else begin
currentdir = -1;
downcount = 1;
upcount = 0;
end;
end;
// išėjimai
if marketposition > 0 and ((barssinceentry >= longexit) or (trendper <> 0 and trend < 0)) then
sell ("Lexit") all contracts this bar on close
else if marketposition < 0 and ((barssinceentry >= shortexit) or
(trendper <> 0 and trend > 0)) then buy to cover ("Sexit") all contracts this bar on close;
// pelno fiksavimas antrąją dieną
if marketposition > 0 and profperiod <> 0 and longproffactor <> 0 then
sell ("LongPT2") all contracts next bar at entryprice + longproffactor*ATRprofit limit;
if marketposition < 0 and profperiod <> 0 and shortproffactor <> 0 then
buy to cover ("ShortPT2") all contracts next bar at entryprice - shortproffactor*ATRprofit limit;
// nauja ilgoji pozicija uždarymo metu arba kito atidarymo metu
// ankstesnė kryptis buvo žemyn, o serijos ilgis pasiekė nustatytą reikšmę
if currentdir <= 0 and downcount >= longentry then begin 
// uždaryti ankstesnę trumpąją poziciją
if marketposition < 0 then buy to cover ("Lreverse") all contracts this bar on close;
// patikrinti kitos dienos sąlygas
volOK = volperiod = 0 or ((minvol = 0 or volratio > minvol) and
(maxvol = 0 or volratio < maxvol));
if (trendper = 0 or trend > 0) and (dontusedayofweek = 0 or dontusedayofweek <> DOW) and volOK then begin
// pavedimas uždarymo metu
buy ("upday") size contracts this bar on close;
// nustatyti pelno tikslą
if profperiod <> 0 and longproffactor <> 0 then
sell ("LongPT") all contracts next bar at entryprice + longproffactor*ATRprofit limit;
end;
end
// nauja trumpoji pozicija
else if longonly = false and currentdir >= 0 and upcount
>= shortentry then begin
// uždaryti ankstesnę ilgąją poziciją
if marketposition > 0 then sell ("Sreverse") all contracts this bar on close;
if (trendper = 0 or trend < 0) and (dontusedayofweek
= 0 or dontusedayofweek <> DOW)
and volOK then begin
// pavedimas uždarymo metu
sell short ("downday") size contracts this bar on close;
// nustatyti pelno tikslą
if profperiod <> 0 and shortproffactor <> 0 then
buy to cover ("ShortPT") all contracts next bar at entryprice - shortproffactor*ATRprofit limit;
end;
end;
// naujos pozicijos šiandienos uždarymo metu
if marketposition = 0 and currentdir[1] <= 0 and
downcount[1] >= longentry and (trendper =
0 or trend[1] > 0) then begin
if close < close[1] and volOK[1] then begin
buy size contracts this bar on close;
end;
end
else if marketposition = 0 and longonly = false and currentdir >= 0 and
upcount[1] >= shortentry and (trendper = 0 or trend[1] < 0) then begin
if close > close[1] and volOK then begin
sell short size contracts this bar on close;
end;
end;